uses
  Registry;
...
 
function GetDirectXVersion: String;
type
  TDXVer = record
    Version : Byte;
    Major   : Word;
    Minor   : Word;
    SubMinor: Word;
  end;
 
var
  Reg  : TRegistry; // класс для работы с реестром
  Str  : String;    // временная переменная
  DXVer: TDXVer;    // структура
begin
  Reg := TRegistry.Create;
  try
    Reg.RootKey := HKEY_LOCAL_MACHINE;
    if Reg.OpenKey('\Software\Microsoft\DirectX', False) then
    begin
      Result := Reg.ReadString('Version');                       // читаем из реестра номер билда
      Str := Result;
      DXVer.Version := StrToInt(Copy(Result, 1, Pos('.', Result)-1));// заполняем нашу структуру, 
      Delete(Result, 1, Pos('.', Result));                           // разбиваем на версии по  
      DXVer.Major := StrToInt(Copy(Result, 1, Pos('.', Result)-1));  // степени значимости
      Delete(Result, 1, Pos('.', Result));                           // (старшая, младшая)
      DXVer.Minor := StrToInt(Copy(Result, 1, Pos('.', Result)-1));
      Delete(Result, 1, Pos('.', Result));
      DXVer.SubMinor := StrToInt(Result);
      Result := '?';
      case DXVer.Version of                                          // анализируем, сравнивая с 
        4: case DXVer.Major of                                       // хронологической таблицей
             5: if DXVer.Minor = 0 then                               
                  Result := '5.0 for Windows NT 5.0' else
                  Result := '5.0 for Windows 98';
             6: if DXVer.Minor = 0 then
                  Result := '6.0' else
                  Result := '6.1';
             7: if DXVer.SubMinor = 700 then
                  Result := '7.0' else
                  Result := '7.0a';
             8: case DXVer.Minor of
                  0: Result := '8.0';
                  1: if DXVer.SubMinor = 901 then
                       Result := '8.1b' else
                       Result := '8.1 for Windows XP';
                end;
             9: case DXVer.SubMinor of
                  900: Result := '9.0';
                  901: Result := '9.0a';
                  902: Result := '9.0b';
                  904: Result := '9.0c';
                  905: Result := '9.0L for Windows Vista';
                end;
            10: Result := '10.' + IntToStr(DXVer.Minor);
           end;
        6: case DXVer.Minor of
             6000: Result := '10.0';
             6001: Result := '10.1';
           end;
      end;
      Result := Result + ' ('+ Str + ')'; // возвращаем название версии + номер билда
    end;
  finally
    Reg.CloseKey;
    Reg.Free;
  end;
end;